2009年6月6日土曜日

[.NET]QRコードの変換

[はじめに]
・最近、仕事でQRコードを扱うシステム開発に携わる機会が多いので、
　.NETでも作ってみました。
　.NET FrameworkではQRコードを標準でサポートしていない為、
　外部のコンポーネントを利用しています。

[関連情報]
・QRコードの仕様　（デンソーウェーブのサイト）
　http://www.qrcode.com
・外部コンポーネント
　「ThoughtWorks.QRCode.dll」を参照しています。
　[Open Source QRCode Library]
からダウンロードできます。
　「ThoughtWorks.QRCode.dll」を参照は、「参照設定」から追加して下さい。
　（※追加しないとコンパイルエラーになります。）
　　参照設定

[ソース]
　QRコードの変換ユーティリティクラスです。
　提供するメソッドは、以下の２つです。
　・Encodeメソッド：文字列をQRコードのイメージに変換する。
　・Decodeメソッド：QRコードのイメージから文字列を取得する。
Imports System.IO
Imports System.Text
Imports ThoughtWorks.QRCode.Codec
Imports ThoughtWorks.QRCode.Codec.Data
Imports ThoughtWorks.QRCode.Codec.Util

''' <summary>
''' QRコード関連のユーティリティ
''' </summary>
''' <remarks></remarks>
Public NotInheritable Class QRCodeUtil

    '[説明]
    '[参照設定]
    '   ThoughtWorks.QRCode.dll
    ' 　上記DLLは、以下のサイトよりダウンロード可能
    ' 　[Open Source QRCode Library]
    ' 　[http://www.codeproject.com/KB/cs/qrcode.aspx]
    '[QRコードの仕様]
    '   デンソーウェーブの下記サイトをご参照下さい。
    '   [QR Code.com]
    '   [http://www.qrcode.com]


    ''' <summary>
    ''' デフォルトのエンコーディング名
    ''' </summary>
    ''' <remarks></remarks>
    Private Const DEFAULT_ENCODING_NAME As String = "shift_jis"

    ''' <summary>
    ''' デフォルトのエンコーディング
    ''' </summary>
    ''' <remarks></remarks>
    Private Shared ReadOnly DEFAULT_ENCODING As Encoding _
             = Encoding.GetEncoding(DEFAULT_ENCODING_NAME)

#Region "文字列をQRコードに変換する。"

    ''' <summary>
    ''' 文字列をQRコードに変換する。
    ''' </summary>
    ''' <param name="txtData">変換元の文字列</param>
    ''' <param name="encMode">情報の種類（Byte／AlphaNumeric／Numeric）</param>
    ''' <param name="errCorrect">誤り訂正能力（L／M／Q／H）</param>
    ''' <param name="scale">1セル当りのピクセル数</param>
    ''' <param name="version">QRコードに格納する情報量を決める型番（１～４０）</param>
    ''' <returns>QRコードのイメージ</returns>
    ''' <remarks></remarks>
    Public Shared Function Encode( _
        ByVal txtData As String, _
        ByVal encMode As QRCodeEncoder.ENCODE_MODE, _
        ByVal errCorrect As QRCodeEncoder.ERROR_CORRECTION, _
        ByVal scale As Integer, _
        ByVal version As Integer _
        ) As Image

        Return Encode( _
            txtData, encMode, errCorrect, _
            scale, version, DEFAULT_ENCODING)
    End Function


    ''' <summary>
    ''' 文字列をQRコードに変換する。
    ''' </summary>
    ''' <param name="txtData">変換元の文字列</param>
    ''' <param name="encMode">情報の種類（Byte／AlphaNumeric／Numeric）</param>
    ''' <param name="errCorrect">誤り訂正能力（L／M／Q／H）</param>
    ''' <param name="scale">1セル当りのピクセル数</param>
    ''' <param name="version">QRコードに格納する情報量を決める型番（１～４０）</param>
    ''' <param name="encoding">エンコーディング</param>
    ''' <returns>QRコードのイメージ</returns>
    ''' <remarks></remarks>
    Public Shared Function Encode( _
        ByVal txtData As String, _
        ByVal encMode As QRCodeEncoder.ENCODE_MODE, _
        ByVal errCorrect As QRCodeEncoder.ERROR_CORRECTION, _
        ByVal scale As Integer, _
        ByVal version As Integer, _
        ByVal encoding As System.Text.Encoding _
        ) As Image

        Dim errMsg As String = Nothing

        Dim qrEnc As QRCodeEncoder = Nothing
        Dim img As Image = Nothing

        '引数チェック
        '[変換元の文字列]
        '   Nothingと空文字列はNGとする。
        If String.IsNullOrEmpty(txtData) Then
            Throw New ArgumentException( _
                "Encode#txtDataが、Nothingか空文字列です。")
        End If

        '[QRコードに格納する情報量を決める型番]
        '   1～40の範囲外はNGとする。
        If version < 1 OrElse version > 40 Then
            errMsg = String.Format( _
                "Versionが範囲外[1～40]です。値:[{0}]", version)
            Throw New ArgumentOutOfRangeException( _
                "Encode#version", errMsg)
        End If

        qrEnc = New QRCodeEncoder()

        '「情報の種類」を設定
        '   QRCodeEncoder.ENCODE_MODE.BYTE
        '   QRCodeEncoder.ENCODE_MODE.NUMERIC
        '   QRCodeEncoder.ENCODE_MODE.ALPHA_NUMERIC
        qrEnc.QRCodeEncodeMode = encMode

        '「誤り訂正能力」を設定
        '   QRCodeEncoder.ERROR_CORRECTION.L
        '   QRCodeEncoder.ERROR_CORRECTION.M
        '   QRCodeEncoder.ERROR_CORRECTION.Q
        '   QRCodeEncoder.ERROR_CORRECTION.H
        qrEnc.QRCodeErrorCorrect = errCorrect

        '「1セル当りのピクセル数」を設定
        '   数値が大きい程、画像のサイズは大きくなる。
        qrEnc.QRCodeScale = scale

        '「QRコードに格納する情報量を決める型番」を設定
        '   1から40までの整数を指定
        '   格納するデータ長が長い程、
        '   より大きいバージョン番号を必要とする。
        '   QRコードを構成するセルの数も多くなる。
        qrEnc.QRCodeVersion = version

        img = qrEnc.Encode(txtData, encoding)

        Return img
    End Function
#End Region

#Region "QRコードのイメージから文字列を復元する。"

    ''' <summary>
    ''' QRコードのイメージから文字列を復元する。
    ''' </summary>
    ''' <param name="imgData">QRコードのイメージ</param>
    ''' <returns>復元後の文字列</returns>
    ''' <remarks></remarks>
    Public Shared Function Decode( _
        ByVal imgData As Image _
        ) As String
        Return Decode(imgData, DEFAULT_ENCODING)
    End Function


    ''' <summary>
    ''' QRコードのイメージから文字列を復元する。
    ''' </summary>
    ''' <param name="imgData">QRコードのイメージ</param>
    ''' <param name="encoding">エンコーディング</param>
    ''' <returns>復元後の文字列</returns>
    ''' <remarks></remarks>
    Public Shared Function Decode( _
        ByVal imgData As Image, _
        ByVal encoding As System.Text.Encoding _
        ) As String

        Dim qrDec As QRCodeDecoder = Nothing
        Dim qrBitmap As QRCodeBitmapImage = Nothing
        Dim txtData As String = Nothing

        '引数チェック
        '[変換元の文字列]
        '   NothingはNGとする。
        If imgData Is Nothing Then
            Throw New ArgumentNullException( _
                "Decode#imgDataがNothingです。")
        End If

        qrDec = New QRCodeDecoder()
        qrBitmap = New QRCodeBitmapImage(New Bitmap(imgData))

        txtData = qrDec.decode(qrBitmap, encoding)

        Return txtData
    End Function

#End Region

End Class
[VB.NET]QRコードの変換ユーティリティ
at 0 件のコメント:
Labels:
登録: 投稿 (Atom)

[雑記]ドローン（DJI Mini 3）

（１）雑記 もともと多趣味の友人 masakazu Drone 氏が、 最近、 ドローン にハマり始めて、 更に、新たな趣味が増えたとのこと。 ドローン を始めてから、 まだ1年も経っていないとのことですが、 旅行先で山や川の景色を 空撮 して、 Youtube ...

  • [雑記]ドローン（DJI Mini 3）
    （１）雑記 もともと多趣味の友人 masakazu Drone 氏が、 最近、 ドローン にハマり始めて、 更に、新たな趣味が増えたとのこと。 ドローン を始めてから、 まだ1年も経っていないとのことですが、 旅行先で山や川の景色を 空撮 して、 Youtube ...
  • [Book's Review (Develop)]Java言語で学ぶデザインパターン入門第３版
    （１）レビュー 　10年以上前からある書籍ですが、昨今のJavaのバージョンに合わせて、 　リニューアルされましたので、改めて紹介いたします。 　GOFが提唱したデザインパターンについて、とてもわかりやすくまとめた１冊です。 　各パターンを章毎にまとめてあり、クラス図・...
  • [SQLServer]sqlcmdコマンドの表示桁数の指定
    （１）はじめに 　 sqlcmd コマンドで、 　SELECTステートメントを実行した時、 　行の折り返しで、結果が見づらくなることがあります。 　 Oracle の LINESIZE に相当する設定が、 　 SQLServer にもないか調べてみました。 　普段...
  • [Hardware's Review]SEIKO CLOCK (セイコークロック) デジタル ウィークリーアラーム
    （１）レビュー 　目覚まし時計の調子が悪くなったので、新たに購入しました。 　指定した時刻にアラームが鳴ってくれさえすればよいので、 　特別な機能は求めていなかったのですが、 　価格の割に便利な機能が搭載されていたので、購入に至りました。 　最近は、スマホにもアラーム...
  • [Algo]和と積から元の２数の算出
    [はじめに] （１） ある２数の和と積から、元の２数を求めるアルゴリズム です。 　　　例えば、『 足して５ 』、『 掛けて６ 』になる２つの数は、 　　　 ２ と ３ になります。 　　　これを解くアルゴリズムとして、 　　　 ２次方程式の解の解法 を利用することがで...
  • [Book's Review (Develop)]ASP.NET MVC 5実践プログラミング
    （１）レビュー 　 ASP.NET は、以下の2種類に大別されます。 　 （１）ASP.NET Web Form 　　　.NET Framework1.0リリース時の頃から導入 　 （２）ASP.NET MVC 　　　.NET Framework4以降に導入 　...
  • [VBA]Excelのシートを並べ替え
    [はじめに] Excelでシートを昇順に並べ替える機会があったので、 備忘録としてサンプルソースを掲載します。 サンプルは昇順ソートですが、引数を変更すると降順にも対応できるようにしています。 [ソース] コードのコピー Optio...
  • [Book's Review (Develop)]独習JavaScript 新版
    （１）レビュー 　JavaScriptは古くからあり、時代と共に進化してきています。 　JavaScriptの独習シリーズは過去にもありましたが、 　最近（2021年）、独習シリーズでJavaScriptの新版が登場しました。 　 クラス 、 反復処理 、 非同期処理 ...
  • [.NET][Edge対応版]プログラムコードの変換（C#、VB.NET→HTML）
    [はじめに] 　・プログラムソース（C#、VB.NET）を 　　ブログ公開用のHTMLに変換するツールです。 　　（コード量が膨大の為、変換処理のみ掲載しています。） [機能] 　　プログラムソースの文字列を、HTMLに変換する。 　　変換後のHTMLは、<ta...
  • [Tool's Review]ステンレスものほし台 ブロー台付き BD-50S 【ブロー台付きで安定性抜群・U型の竿受けで竿の取り外し楽々! 】
    （１）レビュー 　最近、引越しをしました。 　ベランダの物干し竿を固定する位置が転居前よりも高く、 　身長が低い妻にとって家事がしづらいので、 　 物干し台 を購入しました。 　 　組み立て式の為、多少のぐらつきはありますが、 　実際使ってみても全く不便さを感じませ...